diff --git a/2024/day5.exs b/2024/day5.exs
new file mode 100755
index 0000000..19d6699
--- /dev/null
+++ b/2024/day5.exs
@@ -0,0 +1,78 @@
+#!/usr/bin/env elixir
+defmodule Day5 do
+  def part1({updates, _greater?, sorted?}) do
+    updates
+    |> Enum.filter(sorted?)
+    |> Enum.map(&Enum.at(&1, div(length(&1), 2)))
+    |> Enum.sum()
+  end
+
+  def part2({updates, greater?, sorted?}) do
+    updates
+    |> Enum.reject(sorted?)
+    |> Enum.map(&(Enum.sort(&1, greater?) |> Enum.at(div(length(&1), 2))))
+    |> Enum.sum()
+  end
+
+  def input do
+    with [input_filename] <- System.argv(),
+         {:ok, input} <- File.read(input_filename) do
+      [rules_raw, updates_raw] = String.split(input, "\n\n")
+
+      less_than =
+        String.split(rules_raw, ["|", "\n"])
+        |> Enum.map(&String.to_integer/1)
+        |> Enum.chunk_every(2)
+        |> Enum.group_by(fn [a, _] -> a end, fn [_, b] -> b end)
+
+      greater? = fn greater, lesser -> lesser in Map.get(less_than, greater, []) end
+
+      sorted? = fn report ->
+        report
+        |> Enum.chunk_every(2, 1, :discard)
+        |> Enum.all?(fn [greater, lesser] -> greater?.(greater, lesser) end)
+      end
+
+      updates =
+        updates_raw
+        |> String.split("\n", trim: true)
+        |> Enum.map(fn row -> String.split(row, ",") |> Enum.map(&String.to_integer/1) end)
+
+      {updates, greater?, sorted?}
+    else
+      _ -> :error
+    end
+  end
+
+  #######################
+  # HERE BE BOILERPLATE #
+  #######################
+
+  def run do
+    case input() do
+      :error -> print_usage()
+      input -> run_parts_with_timer(input)
+    end
+  end
+
+  defp run_parts_with_timer(input) do
+    run_with_timer(1, fn -> part1(input) end)
+    run_with_timer(2, fn -> part2(input) end)
+  end
+
+  defp run_with_timer(part, fun) do
+    {time, result} = :timer.tc(fun)
+    IO.puts("Part #{part} (completed in #{format_time(time)}):\n")
+    IO.puts("#{inspect(result)}\n")
+  end
+
+  defp format_time(μsec) when μsec < 1_000, do: "#{μsec}μs"
+  defp format_time(μsec) when μsec < 1_000_000, do: "#{μsec / 1000}ms"
+  defp format_time(μsec), do: "#{μsec / 1_000_000}s"
+
+  defp print_usage do
+    IO.puts("Usage: elixir day5.exs input_filename")
+  end
+end
+
+Day5.run()