#!/usr/bin/env elixir
defmodule Day11 do
  def part1(stones) do
    blink(stones, 25)
  end

  def part2(stones) do
    blink(stones, 75)
  end

  def blink(stones, 0), do: stones |> Map.values() |> Enum.sum()

  def blink(stones, times) do
    stones
    |> Enum.reduce(%{}, fn
      {0, count}, next ->
        Map.update(next, 1, count, &(&1 + count))

      {stone, count}, next ->
        string = Integer.to_string(stone)
        size = byte_size(string)

        if rem(size, 2) == 0 do
          {a, b} = String.split_at(string, div(size, 2))

          next
          |> Map.update(String.to_integer(a), count, &(&1 + count))
          |> Map.update(String.to_integer(b), count, &(&1 + count))
        else
          Map.update(next, stone * 2024, count, &(&1 + count))
        end
    end)
    |> blink(times - 1)
  end

  def input do
    with [input_filename] <- System.argv(),
         {:ok, input} <- File.read(input_filename) do
      input
      |> String.split([" ", "\n"], trim: true)
      |> Enum.map(&String.to_integer/1)
      |> Enum.frequencies()
    else
      _ -> :error
    end
  end

  #######################
  # HERE BE BOILERPLATE #
  #######################

  def run do
    case input() do
      :error -> print_usage()
      input -> run_parts_with_timer(input)
    end
  end

  defp run_parts_with_timer(input) do
    run_with_timer(1, fn -> part1(input) end)
    run_with_timer(2, fn -> part2(input) end)
  end

  defp run_with_timer(part, fun) do
    {time, result} = :timer.tc(fun)
    IO.puts("Part #{part} (completed in #{format_time(time)}):\n")
    IO.puts("#{inspect(result)}\n")
  end

  defp format_time(μsec) when μsec < 1_000, do: "#{μsec}μs"
  defp format_time(μsec) when μsec < 1_000_000, do: "#{μsec / 1000}ms"
  defp format_time(μsec), do: "#{μsec / 1_000_000}s"

  defp print_usage do
    IO.puts("Usage: elixir day11.exs input_filename")
  end
end

Day11.run()