#!/usr/bin/env elixir
defmodule Day9 do
  def part1(input) do
    {size, _, spaces, _, disk, files} =
      Enum.reduce(input, {0, 0, 0, true, %{}, []}, fn len,
                                                      {idx, id, spaces, file?, disk, files} ->
        if file? do
          disk = Enum.into(idx..(idx + len - 1), disk, fn i -> {i, id} end)
          files = if file?, do: for(_ <- 1..len, do: id) ++ files, else: files
          {idx + len, id + 1, spaces, not file?, disk, files}
        else
          {idx + len, id, spaces + len, not file?, disk, files}
        end
      end)

    for i <- 0..(size - spaces - 1), reduce: {0, files} do
      {checksum, files} ->
        case Map.fetch(disk, i) do
          {:ok, block} ->
            {checksum + block * i, files}

          :error ->
            [block | files] = files
            {checksum + block * i, files}
        end
    end
    |> elem(0)
  end

  # Super inefficient, but this is the 2nd attempt after trying to be more efficient
  # worked on the sample but not the actual input
  def part2(input) do
    {_, _, _, disk, files} =
      Enum.reduce(input, {0, 0, true, %{}, []}, fn len, {idx, id, file?, disk, files} ->
        if file? do
          disk = Map.put(disk, idx, {:file, id, len})
          files = [{idx, id, len} | files]
          {idx + len, id + 1, not file?, disk, files}
        else
          disk = Map.put(disk, idx, {:space, len})
          {idx + len, id, not file?, disk, files}
        end
      end)

    Enum.reduce(files, disk, fn {idx, id, len}, disk ->
      # This scans the disk every time. Could possibly optimise by storing the known
      # eligible spaces separately
      case Enum.find(0..(idx - 1), &match?({:space, gap} when gap >= len, disk[&1])) do
        nil ->
          disk

        space_idx ->
          {:space, spaces} = Map.fetch!(disk, space_idx)
          disk = disk |> Map.delete(idx) |> Map.put(space_idx, {:file, id, len})

          remainder_spaces = spaces - len

          if remainder_spaces > 0 do
            Map.put(disk, space_idx + len, {:space, remainder_spaces})
          else
            disk
          end
      end
    end)
    |> Enum.reduce(0, fn
      {_idx, {:space, _}}, checksum ->
        checksum

      {idx, {:file, id, len}}, checksum ->
        for idx <- idx..(idx + len - 1), reduce: checksum do
          checksum -> checksum + idx * id
        end
    end)
  end

  def input do
    with [input_filename] <- System.argv(),
         {:ok, input} <- File.read(input_filename) do
      for <<c::binary-1 <- String.trim_trailing(input, "\n")>>, do: String.to_integer(c)
    else
      _ -> :error
    end
  end

  #######################
  # HERE BE BOILERPLATE #
  #######################

  def run do
    case input() do
      :error -> print_usage()
      input -> run_parts_with_timer(input)
    end
  end

  defp run_parts_with_timer(input) do
    run_with_timer(1, fn -> part1(input) end)
    run_with_timer(2, fn -> part2(input) end)
  end

  defp run_with_timer(part, fun) do
    {time, result} = :timer.tc(fun)
    IO.puts("Part #{part} (completed in #{format_time(time)}):\n")
    IO.puts("#{inspect(result)}\n")
  end

  defp format_time(μsec) when μsec < 1_000, do: "#{μsec}μs"
  defp format_time(μsec) when μsec < 1_000_000, do: "#{μsec / 1000}ms"
  defp format_time(μsec), do: "#{μsec / 1_000_000}s"

  defp print_usage do
    IO.puts("Usage: elixir day9.exs input_filename")
  end
end

Day9.run()