#!/usr/bin/env elixir
defmodule Day22 do
  def part1(input) do
    Enum.sum_by(input, fn secret ->
      Enum.reduce(1..2000, secret, fn _, secret -> next(secret) end)
    end)
  end

  def next(secret) do
    secret
    |> then(fn secret -> (secret * 64) |> mix(secret) end)
    |> prune()
    |> then(fn secret -> div(secret, 32) |> mix(secret) end)
    |> prune()
    |> then(fn secret -> (secret * 2048) |> mix(secret) end)
    |> prune()
  end

  def mix(num, secret), do: Bitwise.bxor(secret, num)
  def prune(secret), do: rem(secret, 16_777_216)

  def part2(input) do
    input
    |> Enum.map(fn secret ->
      1..2000
      |> Enum.map_reduce(secret, fn _, secret -> {rem(secret, 10), next(secret)} end)
      |> elem(0)
      |> Enum.chunk_every(5, 1, :discard)
      |> Enum.reduce(%{}, fn [a, b, c, d, bananas], changes ->
        Map.put_new(changes, {b - a, c - b, d - c, bananas - d}, bananas)
      end)
    end)
    |> Enum.reduce(&Map.merge(&1, &2, fn _k, v1, v2 -> v1 + v2 end))
    |> Enum.max_by(fn {_sequence, bananas} -> bananas end)
    |> elem(1)
  end

  def input do
    with [input_filename] <- System.argv(),
         {:ok, input} <- File.read(input_filename) do
      input
      |> String.split("\n", trim: true)
      |> Enum.map(&String.to_integer/1)
    else
      _ -> :error
    end
  end

  #######################
  # HERE BE BOILERPLATE #
  #######################

  def run do
    case input() do
      :error -> print_usage()
      input -> run_parts_with_timer(input)
    end
  end

  defp run_parts_with_timer(input) do
    run_with_timer(1, fn -> part1(input) end)
    run_with_timer(2, fn -> part2(input) end)
  end

  defp run_with_timer(part, fun) do
    {time, result} = :timer.tc(fun)
    IO.puts("Part #{part} (completed in #{format_time(time)}):\n")
    IO.puts("#{inspect(result)}\n")
  end

  defp format_time(μsec) when μsec < 1_000, do: "#{μsec}μs"
  defp format_time(μsec) when μsec < 1_000_000, do: "#{μsec / 1000}ms"
  defp format_time(μsec), do: "#{μsec / 1_000_000}s"

  defp print_usage do
    IO.puts("Usage: elixir day22.exs input_filename")
  end
end

Day22.run()