#!/usr/bin/env elixir
defmodule Day7 do
  def part1(input) do
    Enum.sum_by(input, fn {answer, values} ->
      if solvable?(answer, values), do: answer, else: 0
    end)
  end

  def solvable?(answer, [result]), do: answer == result

  def solvable?(answer, [a, b | rest]) do
    solvable?(answer, [a * b | rest]) or solvable?(answer, [a + b | rest])
  end

  def part2(input) do
    Enum.sum_by(input, fn {answer, values} ->
      if solvable2?(answer, values), do: answer, else: 0
    end)
  end

  def solvable2?(answer, [result]), do: answer == result

  def solvable2?(answer, [a, b | rest]) do
    solvable2?(answer, [a * b | rest]) or solvable2?(answer, [a + b | rest]) or
      solvable2?(answer, [String.to_integer("#{a}#{b}") | rest])
  end

  def input do
    with [input_filename] <- System.argv(),
         {:ok, input} <- File.read(input_filename) do
      input
      |> String.split("\n", trim: true)
      |> Enum.map(fn line ->
        [result | values] =
          line
          |> String.split([":", " "], trim: true)
          |> Enum.map(&String.to_integer/1)

        {result, values}
      end)
    else
      _ -> :error
    end
  end

  #######################
  # HERE BE BOILERPLATE #
  #######################

  def run do
    case input() do
      :error -> print_usage()
      input -> run_parts_with_timer(input)
    end
  end

  defp run_parts_with_timer(input) do
    run_with_timer(1, fn -> part1(input) end)
    run_with_timer(2, fn -> part2(input) end)
  end

  defp run_with_timer(part, fun) do
    {time, result} = :timer.tc(fun)
    IO.puts("Part #{part} (completed in #{format_time(time)}):\n")
    IO.puts("#{inspect(result)}\n")
  end

  defp format_time(μsec) when μsec < 1_000, do: "#{μsec}μs"
  defp format_time(μsec) when μsec < 1_000_000, do: "#{μsec / 1000}ms"
  defp format_time(μsec), do: "#{μsec / 1_000_000}s"

  defp print_usage do
    IO.puts("Usage: elixir day7.exs input_filename")
  end
end

Day7.run()